Files
harfbuzz/test/api/meson.build
T
Behdad EsfahbodandClaude Opus 4.8 d75c58a2e4 [ot] Fix NULL-deref when nullable output arrays are passed to list getters
Several public "list getter" APIs document their output array as nullable
(pass NULL to just query the total count without storing anything), but
their implementations gated the copy only on the count pointer:

    if (count)
    {
      + source.sub_array (start_offset, count)
      | hb_sink (hb_array (out, *count));   // writes through out even if NULL
    }

Passing a non-NULL count with a NULL output array on a populated table
therefore wrote through the NULL pointer and crashed (SIGSEGV).

Gate each copy on the output pointer as well (the same idiom already used
by hb_color_line_get_color_stops: "if (count && out)").  This is a no-op
when the output array is non-NULL and restores the documented behaviour of
returning the total count when it is NULL.  Affected getters:

  - hb_ot_color_palette_get_colors            (CPAL)
  - hb_ot_color_glyph_get_layers              (COLR v0)
  - hb_ot_meta_get_entry_tags                 (meta)
  - hb_aat_layout_get_feature_types           (AAT feat)
  - hb_aat_layout_feature_type_get_selector_infos (AAT feat)
  - hb_ot_layout_feature_get_characters       (GSUB cvXX)
  - hb_ot_layout_lookup_get_glyph_alternates  (GSUB aalt)

Add test/api/test-ot-nullable-output.c exercising each route with a NULL
output array; every case crashed before this change.

Fixes: GHSA-v5mv-8hhw-vff8
Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
2026-07-08 00:28:35 -06:00

176 lines
4.1 KiB
Meson

if conf.get('HAVE_GLIB', 0) == 0
message('You need to have glib support enabled to run test/api tests')
subdir_done()
endif
tests = [
'test-aat-layout.c',
'test-baseline.c',
'test-base-minmax.c',
'test-be-glyph-advance.c',
'test-be-num-glyphs.c',
'test-blob.c',
'test-buffer.c',
'test-c.c',
'test-collect-unicodes.c',
'test-cplusplus.cc',
'test-common.c',
'test-draw.c',
'test-draw-varc.c',
'test-extents.c',
'test-face.c',
'test-font.c',
'test-font-scale.c',
'test-get-table-tags.c',
'test-glyph-names.c',
'test-instance-cff2.c',
'test-map.c',
'test-object.c',
'test-ot-alternates.c',
'test-ot-collect-glyphs.c',
'test-ot-color.c',
'test-ot-face.c',
'test-ot-glyphname.c',
'test-ot-layout.c',
'test-ot-ligature-carets.c',
'test-ot-name.c',
'test-ot-nullable-output.c',
'test-ot-math.c',
'test-ot-meta.c',
'test-ot-metrics.c',
'test-ot-tag.c',
'test-ot-extents-cff.c',
'test-ot-metrics-tt-var.c',
'test-paint.c',
'test-subset-repacker.c',
'test-set.c',
'test-shape.c',
'test-shape-plan.c',
'test-style.c',
'test-subset.c',
'test-subset-cmap.c',
'test-subset-drop-tables.c',
'test-subset-glyf.c',
'test-subset-hdmx.c',
'test-subset-hmtx.c',
'test-subset-nameids.c',
'test-subset-os2.c',
'test-subset-post.c',
'test-subset-vmtx.c',
'test-subset-cff1.c',
'test-subset-cff2.c',
'test-subset-gvar.c',
'test-subset-hvar.c',
'test-subset-vvar.c',
'test-subset-sbix.c',
'test-subset-gpos.c',
'test-subset-colr.c',
'test-subset-cbdt.c',
'test-unicode.c',
'test-var-coords.c',
'test-version.c',
]
if conf.get('HAVE_FREETYPE', 0) == 1
tests += [
'test-ft.c',
]
endif
if conf.get('HAVE_CORETEXT', 0) == 1
tests += [
'test-coretext.c',
]
endif
if conf.get('HAVE_DIRECTWRITE', 0) == 1
tests += [
'test-directwrite.cc',
]
endif
if conf.get('HAVE_PTHREAD', 0) == 1
tests += 'test-multithread.c'
endif
# Default test running environment
env = environment()
env.set('MALLOC_CHECK_', '1')
env.set('G_DEBUG', 'gc-friendly')
env.set('G_TEST_SRCDIR', meson.current_source_dir())
env.set('G_TEST_BUILDDIR', meson.current_build_dir())
foreach source : tests
cpp_args = []
test_name = source.split('.')[0]
deps = [libharfbuzz_dep,
libharfbuzz_cairo_dep,
libharfbuzz_icu_dep]
suite = ['api']
if test_name.contains('-subset') or test_name.contains('-instance')
if get_option('subset').disabled()
continue
endif
deps += libharfbuzz_subset_dep
suite += 'subset'
endif
if test_name.contains('-instance')
cpp_args += '-DHB_EXPERIMENTAL_API'
endif
test(test_name, executable(test_name, source,
cpp_args: cpp_args,
include_directories: [incconfig],
dependencies: deps,
install: false,
),
protocol: 'tap',
env: env,
suite: suite)
endforeach
if get_option('harfrust').enabled()
harfrust_shape_env = environment()
harfrust_shape_env.set('MALLOC_CHECK_', '1')
harfrust_shape_env.set('G_DEBUG', 'gc-friendly')
harfrust_shape_env.set('G_TEST_SRCDIR', meson.current_source_dir())
harfrust_shape_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
harfrust_shape_env.set('HB_SHAPER_LIST', 'harfrust')
test('test-shape-harfrust',
executable('test-shape-harfrust', 'test-shape.c',
include_directories: [incconfig],
dependencies: [libharfbuzz_dep, libharfbuzz_cairo_dep, libharfbuzz_icu_dep],
install: false,
),
protocol: 'tap',
env: harfrust_shape_env,
suite: ['api', 'harfrust'])
endif
if not get_option('raster').disabled()
test('test-raster',
executable('test-raster', 'test-raster.cc',
include_directories: [incconfig],
dependencies: [libharfbuzz_raster_dep],
install: false,
),
protocol: 'tap',
env: env,
suite: ['api', 'raster'])
endif
if not get_option('gpu').disabled()
test('test-gpu',
executable('test-gpu', 'test-gpu.cc',
include_directories: [incconfig],
dependencies: [libharfbuzz_gpu_dep],
install: false,
),
protocol: 'tap',
env: env,
suite: ['api', 'gpu'])
endif