Files
harfbuzz/test/api/meson.build
T
ff217d3039 [graphite2] Fix cluster values when the buffer was reversed (#6156)
When the requested direction differs from the script's horizontal
direction, the Graphite2 shaper reverses the buffer before segmenting.
Input cluster values then decrease along the buffer, so assigning each
Graphite group the cluster of its base character can leave earlier
characters outside the resulting cluster map.

Preserve the source span of every Graphite glyph while constructing the
output. At monotone cluster levels, seed each glyph from the minimum
endpoint of that span and use merge_clusters() over each Graphite output
range. Keep the historical base-character behavior at non-monotone
levels.

HarfBuzz cluster values are opaque client labels and can be repeated or
gapped. Merging them can therefore coalesce multiple Graphite layout
groups. Preserve the Graphite group index separately for positioning so
every group's advance is emitted even when its HarfBuzz cluster was
merged. Validate Graphite slot source bounds before indexing the input.

Add shape regressions using a subset of Awami Nastaliq and an API test
with repeated input clusters. The latter used to merge the output
clusters correctly but drop an entire layout-group advance, reducing
the total from 3200 to 1269.

Tested with:
meson test -C build test-graphite2
meson test -C build --suite shape
meson test -C build



Assisted-by: Codex <codex@openai.com>

Co-authored-by: Michael Brown <michael.brown@rubicotech.com>
Co-authored-by: Claude Fable 5 <noreply@anthropic.com>
2026-08-22 12:48:13 -06:00

186 lines
4.3 KiB
Meson

if conf.get('HAVE_GLIB', 0) == 0
message('You need to have glib support enabled to run test/api tests')
subdir_done()
endif
tests = [
'test-aat-layout.c',
'test-baseline.c',
'test-base-minmax.c',
'test-be-glyph-advance.c',
'test-be-num-glyphs.c',
'test-blob.c',
'test-buffer.c',
'test-c.c',
'test-collect-unicodes.c',
'test-cplusplus.cc',
'test-common.c',
'test-draw.c',
'test-draw-varc.c',
'test-extents.c',
'test-face.c',
'test-font.c',
'test-font-scale.c',
'test-get-table-tags.c',
'test-glyph-names.c',
'test-instance-cff2.c',
'test-map.c',
'test-object.c',
'test-ot-alternates.c',
'test-ot-collect-glyphs.c',
'test-ot-color.c',
'test-ot-face.c',
'test-ot-fetch.c',
'test-ot-glyphname.c',
'test-ot-layout.c',
'test-ot-ligature-carets.c',
'test-ot-name.c',
'test-ot-nullable-output.c',
'test-ot-math.c',
'test-ot-meta.c',
'test-ot-metrics.c',
'test-ot-tag.c',
'test-ot-extents-cff.c',
'test-ot-metrics-tt-var.c',
'test-paint.c',
'test-subset-repacker.c',
'test-set.c',
'test-shape.c',
'test-shape-plan.c',
'test-style.c',
'test-subset.c',
'test-subset-avar2.c',
'test-subset-cmap.c',
'test-subset-drop-tables.c',
'test-subset-glyf.c',
'test-subset-hdmx.c',
'test-subset-hmtx.c',
'test-subset-nameids.c',
'test-subset-os2.c',
'test-subset-post.c',
'test-subset-vmtx.c',
'test-subset-cff1.c',
'test-subset-cff2.c',
'test-subset-gvar.c',
'test-subset-hvar.c',
'test-subset-vvar.c',
'test-subset-sbix.c',
'test-subset-gpos.c',
'test-subset-colr.c',
'test-subset-cbdt.c',
'test-unicode.c',
'test-var-coords.c',
'test-version.c',
]
if conf.get('HAVE_FREETYPE', 0) == 1
tests += [
'test-ft.c',
]
endif
if conf.get('HAVE_GRAPHITE2', 0) == 1
tests += 'test-graphite2.c'
endif
if conf.get('HAVE_CORETEXT', 0) == 1
tests += [
'test-coretext.c',
]
endif
if conf.get('HAVE_DIRECTWRITE', 0) == 1
tests += [
'test-directwrite.cc',
]
endif
if conf.get('HAVE_PTHREAD', 0) == 1
tests += 'test-multithread.c'
endif
if conf.get('HB_EXPERIMENTAL_API', 0) == 1
tests += 'test-ot-depend.c'
endif
# Default test running environment
env = environment()
env.set('MALLOC_CHECK_', '1')
env.set('G_DEBUG', 'gc-friendly')
env.set('G_TEST_SRCDIR', meson.current_source_dir())
env.set('G_TEST_BUILDDIR', meson.current_build_dir())
foreach source : tests
cpp_args = []
test_name = source.split('.')[0]
deps = [libharfbuzz_dep,
libharfbuzz_cairo_dep,
libharfbuzz_icu_dep]
suite = ['api']
if test_name.contains('-subset') or test_name.contains('-instance') or test_name.contains('-depend')
if get_option('subset').disabled()
continue
endif
deps += libharfbuzz_subset_dep
suite += 'subset'
endif
if test_name.contains('-instance')
cpp_args += '-DHB_EXPERIMENTAL_API'
endif
test(test_name, executable(test_name, source,
cpp_args: cpp_args,
include_directories: [incconfig],
dependencies: deps,
install: false,
),
protocol: 'tap',
env: env,
suite: suite)
endforeach
if get_option('harfrust').enabled()
harfrust_shape_env = environment()
harfrust_shape_env.set('MALLOC_CHECK_', '1')
harfrust_shape_env.set('G_DEBUG', 'gc-friendly')
harfrust_shape_env.set('G_TEST_SRCDIR', meson.current_source_dir())
harfrust_shape_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
harfrust_shape_env.set('HB_SHAPER_LIST', 'harfrust')
test('test-shape-harfrust',
executable('test-shape-harfrust', 'test-shape.c',
include_directories: [incconfig],
dependencies: [libharfbuzz_dep, libharfbuzz_cairo_dep, libharfbuzz_icu_dep],
install: false,
),
protocol: 'tap',
env: harfrust_shape_env,
suite: ['api', 'harfrust'])
endif
if not get_option('raster').disabled()
test('test-raster',
executable('test-raster', 'test-raster.cc',
include_directories: [incconfig],
dependencies: [libharfbuzz_raster_dep],
install: false,
),
protocol: 'tap',
env: env,
suite: ['api', 'raster'])
endif
if not get_option('gpu').disabled()
test('test-gpu',
executable('test-gpu', 'test-gpu.cc',
include_directories: [incconfig],
dependencies: [libharfbuzz_gpu_dep],
install: false,
),
protocol: 'tap',
env: env,
suite: ['api', 'gpu'])
endif