Files
wgpu/naga/tests/in/skybox.wgsl
T
Jamie Nicol 78e35c4a7e [naga wgsl-in] Disallow named component expression for matrix types
The WGSL spec only allows named component expressions when the base
type is a vector or a structure, so this patch removes support for it
for matrices. Additionally tests which used this for matrices have
been updated to use indexing expressions instead, and a test has been
added to ensure a named component expression on a matrix results in an
error.
2025-01-07 13:46:41 +01:00

39 lines
983 B
WebGPU Shading Language

struct VertexOutput {
@builtin(position) position: vec4<f32>,
@location(0) uv: vec3<f32>,
}
struct Data {
proj_inv: mat4x4<f32>,
view: mat4x4<f32>,
}
@group(0) @binding(0)
var<uniform> r_data: Data;
@vertex
fn vs_main(@builtin(vertex_index) vertex_index: u32) -> VertexOutput {
// hacky way to draw a large triangle
var tmp1 = i32(vertex_index) / 2;
var tmp2 = i32(vertex_index) & 1;
let pos = vec4<f32>(
f32(tmp1) * 4.0 - 1.0,
f32(tmp2) * 4.0 - 1.0,
0.0,
1.0,
);
let inv_model_view = transpose(mat3x3<f32>(r_data.view[0].xyz, r_data.view[1].xyz, r_data.view[2].xyz));
let unprojected = r_data.proj_inv * pos;
return VertexOutput(pos, inv_model_view * unprojected.xyz);
}
@group(0) @binding(1)
var r_texture: texture_cube<f32>;
@group(0) @binding(2)
var r_sampler: sampler;
@fragment
fn fs_main(in: VertexOutput) -> @location(0) vec4<f32> {
return textureSample(r_texture, r_sampler, in.uv);
}